Show notes: The agent is in - Episode 22 - Hackathon: Termux Services

bundle agent __main__
{
  services:
      "sshd"
        service_policy => "stopped",
        service_method => termux_services;

}

bundle agent termux_services(service, policy)
# @brief Manage service state in Termux
# @param service The name of the service to manage, e.g. `sshd`
# @param policy The desired state of the service (`running`|`stopped`)
{
  classes:
      "service_running"
        expression => regcmp(
          "^run:.*",
          execresult("sv status ${service}", "useshell")
        );

      "service_stopped"
        expression => regcmp(
          "^down:.*",
          execresult("sv status ${service}", "useshell")
        );

      "policy_running"
        expression => strcmp("${policy}", "running");
      "policy_stopped"
        expression => strcmp("${policy}", "stopped");

  commands:
    service_stopped.policy_running::
      "sv up ${service}"
        contain => useshell;

    service_running.policy_stopped::
      "sv down ${service}"
        contain => useshell;
}

body service_method termux_services
{
  service_bundle => default:termux_services(
    ${this.promiser}, ${this.service_policy});
}

body contain useshell
{
  useshell => "useshell";
}